小型FMラジオの作成

#include <Arduino.h>
#include <Wire.h>
#include <radio.h>
#include <RDA5807M.h>
#include <ST7032.h>
#include "Rotary.h"
// RDA5807M BAND
#define FIX_BAND RADIO_BAND_FMWORLD

// Enconder PINs
#define ENCODER_PIN_A 2
#define ENCODER_PIN_B 3
#define ENCODER_SW    4
// Encoder control variables
volatile int encoderCount = 0;
// Encoder control
Rotary encoder = Rotary(ENCODER_PIN_A, ENCODER_PIN_B);

RDA5807M radio;
ST7032 lcd(0x3E);
// 登録放送局名
String STATION_NAME[11] = {"AIR-G           ",
                           "FM North Wave   ",
                           "NHK FM          ",
                           "STV Radio(FM)   ",
                           "HBC Radio(FM)   ",
                           "FM ENIWA        ",
                           "FM IRUKA        ",
                           "FM maple        ",
                           "FM HAMANASU     ",
                           "FM SHIROISHI    ",
                           "                "
                          };
// 登録放送局周波数 x100MHz
unsigned int STATION_FREQ[11] = { 8040, 8250, 8520, 9040, 9150, 7780, 8070, 7990, 7610, 8300, 0000};

int VOL = 1;
int CH = 4;     // 初期チャンネル設定
char  MODE = 0; // 0:freq, 2:ch, 3:vol
unsigned int FREQ = STATION_FREQ[CH];
String  MODE_NAME[3] = {"FREQ", "CH.", "Vol"};

void setup() {
  Wire.begin();
  // open the Serial port
  Serial.begin(57600);
  Serial.println("Radio...");
  delay(200);
  // Initialize LCD
  lcd.begin(16, 2);
  lcd.setContrast(0x0E);
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("RDA5807 FM Radio");
  lcd.setCursor(0, 1);
  lcd.print("        Ver. 1.0");
  delay(3000);
  lcd.clear();

  // Initialize the Radio
  radio.init();
  radio.debugEnable();
  radio.setBand(FIX_BAND);
  radio.setFrequency(FREQ);
  radio.setVolume(VOL);
  radio.setMono(false);
  radio.setMute(false);

  lcd.setCursor(0, 1);
  lcd.print(MODE_NAME[MODE]);
  radio.setFrequency(FREQ);
  showFreq();

  // Encoder interrupt
  pinMode(ENCODER_PIN_A, INPUT_PULLUP);
  pinMode(ENCODER_PIN_B, INPUT_PULLUP);
  pinMode(ENCODER_SW, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(ENCODER_PIN_A), rotaryEncoder, CHANGE);
  attachInterrupt(digitalPinToInterrupt(ENCODER_PIN_B), rotaryEncoder, CHANGE);
} // setup

void loop() {
  char sw;

  while (1) {
    sw = digitalRead( ENCODER_SW );
    if ( sw == LOW ) {
      delay(200);
      MODE++;
      if ( MODE > 2 ) MODE = 0;
      lcd.setCursor(0, 1);
      lcd.print("     ");
      lcd.setCursor(0, 1);
      lcd.print(MODE_NAME[MODE]);
      if ( MODE == 1 ) showChannel();
      if ( MODE == 2 ) showVol();
    }

    if (encoderCount != 0) {
      switch (MODE) {
        // freq
        case 0:
          if (encoderCount == 1) {
            FREQ = FREQ + 10;
          }
          else {
            FREQ = FREQ - 10;
          }
          radio.setFrequency(FREQ);
          showFreq();
          encoderCount = 0;
          break;
        // ch
        case 1:
          if (encoderCount == 1) {
            CH = CH + (CH < 9);
          }
          else {
            CH = CH - (CH > 0 );
          }
          FREQ = STATION_FREQ[CH];
          radio.setFrequency(FREQ);
          showFreq();
          showChannel();
          encoderCount = 0;
          break;
        // Vol
        case 2:
          if (encoderCount == 1) {
            VOL = VOL + (VOL < 15);
          }
          else {
            VOL = VOL - (VOL > 0);
          }
          radio.setVolume(VOL);
          showVol();
          encoderCount = 0;
          break;

        default:
          break;
      }
    }
  }
} // loop

void showFreq() {
  int i;
  char  disp[17];
  char  freq[7];
  bool CH_FLG;

  for ( i = 0 ; i < 17 ; i++ ) {
    if ( i < 7 ) freq[i] = 0 ;
    disp[i] = 0;
  }

  sprintf(freq, "%5d", FREQ);
  freq[5] = freq[4];
  freq[4] = freq[3];
  freq[3] = '.';
  sprintf(disp, " %sMHz", freq);
  lcd.setCursor(6, 1);
  lcd.print(disp);
  CH_FLG = false;
  for ( i = 0 ; i < 10 ; i++ ) {
    if ( FREQ == STATION_FREQ[i] ) {
      CH = i;
      CH_FLG = true;
      break;
    }
  }
  lcd.setCursor(0, 0);
  if ( CH_FLG == true) {
    lcd.print(STATION_NAME[CH]);
  }
  else {
    lcd.print("                ");
  }
}

void showChannel() {
  int i;
  char  disp[17];
  char  ch_num[3];

  for ( i = 0 ; i < 17 ; i++ ) {
    if ( i < 3 ) ch_num[i] = 0;
    disp[i] = 0;
  }

  sprintf(ch_num, "%2d", CH + 1);
  lcd.setCursor(3, 1);
  lcd.print(ch_num);
  lcd.setCursor(0, 0);
  lcd.print(STATION_NAME[CH]);
}

void showVol() {
  int i;
  char  num_vol[3];

  for ( i = 0 ; i < 3 ; i++) num_vol[i] = 0;
  sprintf(num_vol, "%2d", VOL);
  lcd.setCursor(3, 1);
  lcd.print(num_vol);
}

void rotaryEncoder() {
  uint8_t encoderStatus = encoder.process();
  if (encoderStatus)
    encoderCount = (encoderStatus == DIR_CW) ? 1 : -1;
}
// End.